Finding a cluster of closest points

$ontext

  find cluster of m=8 points closest to each other

  compare:
       simple greedy heuristic (HEURISTIC)
       quadratic model (MIQP)
       linearized model (MIP)
       minmax model (MINMAX)

$offtext

set
  c 'coordinates'/x,y/
  i 'points'/point1*point50/
;

scalar m 'number of points to select'/8/;

parameter coord(i,c) 'random coordinates';
coord(i,c) = uniform(0,1);
display coord;

alias(i,j);
set ij(i,j) 'upper triangular structure';
ij(i,j) = ord(i) < ord(j);

parameter dist(i,j) 'euclidean distances';
dist(ij(i,j)) = sqrt(sum(c, sqr(coord(i,c)-coord(j,c))));

binaryvariables x(i) 'selected points';
positivevariable y(i,j) 'x(i)*x(j), relaxed to be continuous';
y.up(ij)=1;

variable z 'objective';

equations
    obj1  'quadratic objective'
    obj2  'linearized objective'
    obj3  'minmax objective'
    select 'number of selected points'
    bound  'implication x(i)=x(j)=1 ==> y(i,j)=1'
;

obj1.. z =e= sum(ij(i,j), x(i)*x(j)*dist(ij));
obj2.. z =e= sum(ij, y(ij)*dist(ij));
obj3(ij).. z =g= y(ij)*dist(ij);
select.. sum(i, x(i)) =e= m;
bound(ij(i,j))..  y(i,j) =g= x(i) + x(j) - 1;

model m1 /obj1,select/;
model m2 /obj2,select,bound/;
model m3 /obj3,select,bound/;
option optcr=0,mip=cplex,miqcp=cplex,threads=8;

*------------------------------------------------
* reporting macros
*------------------------------------------------

parameter results(*,*);

set dummy 'ordering for output'/  status,obj,sum,max,time,'gap%'/;

acronym TimeLimit;
acronym Optimal;

* macros for reporting
$macro sumdist    sum(ij(i,j), x.l(i)*x.l(j)*dist(ij))
$macro maxdist    smax(ij(i,j), x.l(i)*x.l(j)*dist(ij))
$macro report(m,label)  \
    x.l(i) = round(x.l(i));  \
    results(i,label) = x.l(i); \
    results('status',label)$(m.solvestat=1) = Optimal; \
    results('status',label)$(m.solvestat=3) = TimeLimit; \
    results('obj',label) = z.l; \
    results('sum',label) = sumdist; \
    results('max',label) = maxdist; \
    results('time',label) = m.resusd; \
    results('gap%',label)$(m.solvestat=3) = 100*abs(m.objest - m.objval)/abs(m.objest);


*------------------------------------------------
* heuristic
*------------------------------------------------


* step 1 : select points 1 and 2 by minimizing distance
scalar dmin,dmin1,dmin2;
dmin = smin(ij,dist(ij));
loop(ij(i,j)$(dist(ij)=dmin),
   x.l(i)=1;
   x.l(j)=1;
   break;
);

* add points 3..m, closest to points selected earlier
scalar k;
for(k = 3 to m,
   dmin = smin(ij(i,j)$(x.l(i) xor x.l(j)), dist(ij));
   loop(ij(i,j)$(dist(ij)=dmin),
     x.l(i)=1;
     x.l(j)=1;
     break;
   );
);

results(i,'HEURISTIC') = x.l(i);
results('sum','HEURISTIC') = sumdist;
results('max','HEURISTIC') = maxdist;


*------------------------------------------------
* run models m1 through m3
*------------------------------------------------

solve m1 minimizing z using miqcp;
report(m1,'MIQP')

solve m2 minimizing z using mip;
report(m2,'MIP')

solve m3 minimizing z using mip;
report(m3,'MINMAX')

display results;